1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
|
// Copyright 2009 The Go Authors. All rights reserved.
// Use of this source code is governed by a BSD-style
// license that can be found in the LICENSE file.
//
// System calls and other sys.stuff for ARM, OpenBSD
// /usr/src/sys/kern/syscalls.master for syscall numbers.
//
#include "go_asm.h"
#include "go_tls.h"
#include "textflag.h"
#define CLOCK_REALTIME $0
#define CLOCK_MONOTONIC $3
// With OpenBSD 6.7 onwards, an armv7 syscall returns two instructions
// after the SWI instruction, to allow for a speculative execution
// barrier to be placed after the SWI without impacting performance.
// For now use hardware no-ops as this works with both older and newer
// kernels. After OpenBSD 6.8 is released this should be changed to
// speculation barriers.
#define NOOP MOVW R0, R0
#define INVOKE_SYSCALL \
SWI $0; \
NOOP; \
NOOP
// mstart_stub is the first function executed on a new thread started by pthread_create.
// It just does some low-level setup and then calls mstart.
// Note: called with the C calling convention.
TEXT runtime·mstart_stub(SB),NOSPLIT,$0
// R0 points to the m.
// We are already on m's g0 stack.
// Save callee-save registers.
MOVM.DB.W [R4-R11], (R13)
MOVW m_g0(R0), g
BL runtime·save_g(SB)
BL runtime·mstart(SB)
// Restore callee-save registers.
MOVM.IA.W (R13), [R4-R11]
// Go is all done with this OS thread.
// Tell pthread everything is ok (we never join with this thread, so
// the value here doesn't really matter).
MOVW $0, R0
RET
TEXT runtime·sigfwd(SB),NOSPLIT,$0-16
MOVW sig+4(FP), R0
MOVW info+8(FP), R1
MOVW ctx+12(FP), R2
MOVW fn+0(FP), R3
MOVW R13, R9
SUB $24, R13
BIC $0x7, R13 // alignment for ELF ABI
BL (R3)
MOVW R9, R13
RET
TEXT runtime·sigtramp(SB),NOSPLIT,$0
// Reserve space for callee-save registers and arguments.
MOVM.DB.W [R4-R11], (R13)
SUB $16, R13
// If called from an external code context, g will not be set.
// Save R0, since runtime·load_g will clobber it.
MOVW R0, 4(R13) // signum
BL runtime·load_g(SB)
MOVW R1, 8(R13)
MOVW R2, 12(R13)
BL runtime·sigtrampgo(SB)
// Restore callee-save registers.
ADD $16, R13
MOVM.IA.W (R13), [R4-R11]
RET
TEXT ·publicationBarrier(SB),NOSPLIT|NOFRAME,$0-0
B runtime·armPublicationBarrier(SB)
// TODO(jsing): OpenBSD only supports GOARM=7 machines... this
// should not be needed, however the linker still allows GOARM=5
// on this platform.
TEXT runtime·read_tls_fallback(SB),NOSPLIT|NOFRAME,$0
MOVM.WP [R1, R2, R3, R12], (R13)
MOVW $330, R12 // sys___get_tcb
INVOKE_SYSCALL
MOVM.IAW (R13), [R1, R2, R3, R12]
RET
// These trampolines help convert from Go calling convention to C calling convention.
// They should be called with asmcgocall - note that while asmcgocall does
// stack alignment, creation of a frame undoes it again.
// A pointer to the arguments is passed in R0.
// A single int32 result is returned in R0.
// (For more results, make an args/results structure.)
TEXT runtime·pthread_attr_init_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 0(R0), R0 // arg 1 attr
CALL libc_pthread_attr_init(SB)
MOVW R9, R13
RET
TEXT runtime·pthread_attr_destroy_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 0(R0), R0 // arg 1 attr
CALL libc_pthread_attr_destroy(SB)
MOVW R9, R13
RET
TEXT runtime·pthread_attr_getstacksize_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 size
MOVW 0(R0), R0 // arg 1 attr
CALL libc_pthread_attr_getstacksize(SB)
MOVW R9, R13
RET
TEXT runtime·pthread_attr_setdetachstate_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 state
MOVW 0(R0), R0 // arg 1 attr
CALL libc_pthread_attr_setdetachstate(SB)
MOVW R9, R13
RET
TEXT runtime·pthread_create_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
SUB $16, R13
BIC $0x7, R13 // align for ELF ABI
MOVW 0(R0), R1 // arg 2 attr
MOVW 4(R0), R2 // arg 3 start
MOVW 8(R0), R3 // arg 4 arg
MOVW R13, R0 // arg 1 &threadid (discarded)
CALL libc_pthread_create(SB)
MOVW R9, R13
RET
TEXT runtime·thrkill_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 - signal
MOVW $0, R2 // arg 3 - tcb
MOVW 0(R0), R0 // arg 1 - tid
CALL libc_thrkill(SB)
MOVW R9, R13
RET
TEXT runtime·thrsleep_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
SUB $16, R13
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 - clock_id
MOVW 8(R0), R2 // arg 3 - abstime
MOVW 12(R0), R3 // arg 4 - lock
MOVW 16(R0), R4 // arg 5 - abort (on stack)
MOVW R4, 0(R13)
MOVW 0(R0), R0 // arg 1 - id
CALL libc_thrsleep(SB)
MOVW R9, R13
RET
TEXT runtime·thrwakeup_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 - count
MOVW 0(R0), R0 // arg 1 - id
CALL libc_thrwakeup(SB)
MOVW R9, R13
RET
TEXT runtime·exit_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 0(R0), R0 // arg 1 exit status
BL libc_exit(SB)
MOVW $0, R8 // crash on failure
MOVW R8, (R8)
MOVW R9, R13
RET
TEXT runtime·getthrid_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
MOVW R0, R8
BIC $0x7, R13 // align for ELF ABI
BL libc_getthrid(SB)
MOVW R0, 0(R8)
MOVW R9, R13
RET
TEXT runtime·raiseproc_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW R0, R4
BL libc_getpid(SB) // arg 1 pid
MOVW R4, R1 // arg 2 signal
BL libc_kill(SB)
MOVW R9, R13
RET
TEXT runtime·sched_yield_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
BL libc_sched_yield(SB)
MOVW R9, R13
RET
TEXT runtime·mmap_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
SUB $16, R13
BIC $0x7, R13 // align for ELF ABI
MOVW R0, R8
MOVW 4(R0), R1 // arg 2 len
MOVW 8(R0), R2 // arg 3 prot
MOVW 12(R0), R3 // arg 4 flags
MOVW 16(R0), R4 // arg 5 fid (on stack)
MOVW R4, 0(R13)
MOVW $0, R5 // pad (on stack)
MOVW R5, 4(R13)
MOVW 20(R0), R6 // arg 6 offset (on stack)
MOVW R6, 8(R13) // low 32 bits
MOVW $0, R7
MOVW R7, 12(R13) // high 32 bits
MOVW 0(R0), R0 // arg 1 addr
BL libc_mmap(SB)
MOVW $0, R1
CMP $-1, R0
BNE ok
BL libc_errno(SB)
MOVW (R0), R1 // errno
MOVW $0, R0
ok:
MOVW R0, 24(R8)
MOVW R1, 28(R8)
MOVW R9, R13
RET
TEXT runtime·munmap_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 len
MOVW 0(R0), R0 // arg 1 addr
BL libc_munmap(SB)
CMP $-1, R0
BNE 3(PC)
MOVW $0, R8 // crash on failure
MOVW R8, (R8)
MOVW R9, R13
RET
TEXT runtime·madvise_trampoline(SB), NOSPLIT, $0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 len
MOVW 8(R0), R2 // arg 3 advice
MOVW 0(R0), R0 // arg 1 addr
BL libc_madvise(SB)
// ignore failure - maybe pages are locked
MOVW R9, R13
RET
TEXT runtime·open_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
SUB $8, R13
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 - flags
MOVW 8(R0), R2 // arg 3 - mode (vararg, on stack)
MOVW R2, 0(R13)
MOVW 0(R0), R0 // arg 1 - path
MOVW R13, R4
BIC $0x7, R13 // align for ELF ABI
BL libc_open(SB)
MOVW R9, R13
RET
TEXT runtime·close_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 0(R0), R0 // arg 1 - fd
BL libc_close(SB)
MOVW R9, R13
RET
TEXT runtime·read_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 - buf
MOVW 8(R0), R2 // arg 3 - count
MOVW 0(R0), R0 // arg 1 - fd
BL libc_read(SB)
CMP $-1, R0
BNE noerr
BL libc_errno(SB)
MOVW (R0), R0 // errno
RSB.CS $0, R0 // caller expects negative errno
noerr:
MOVW R9, R13
RET
TEXT runtime·write_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 buf
MOVW 8(R0), R2 // arg 3 count
MOVW 0(R0), R0 // arg 1 fd
BL libc_write(SB)
CMP $-1, R0
BNE noerr
BL libc_errno(SB)
MOVW (R0), R0 // errno
RSB.CS $0, R0 // caller expects negative errno
noerr:
MOVW R9, R13
RET
TEXT runtime·pipe2_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 flags
MOVW 0(R0), R0 // arg 1 filedes
BL libc_pipe2(SB)
CMP $-1, R0
BNE 3(PC)
BL libc_errno(SB)
MOVW (R0), R0 // errno
RSB.CS $0, R0 // caller expects negative errno
MOVW R9, R13
RET
TEXT runtime·setitimer_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 new
MOVW 8(R0), R2 // arg 3 old
MOVW 0(R0), R0 // arg 1 which
BL libc_setitimer(SB)
MOVW R9, R13
RET
TEXT runtime·usleep_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 0(R0), R0 // arg 1 usec
BL libc_usleep(SB)
MOVW R9, R13
RET
TEXT runtime·sysctl_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
SUB $8, R13
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 miblen
MOVW 8(R0), R2 // arg 3 out
MOVW 12(R0), R3 // arg 4 size
MOVW 16(R0), R4 // arg 5 dst (on stack)
MOVW R4, 0(R13)
MOVW 20(R0), R5 // arg 6 ndst (on stack)
MOVW R5, 4(R13)
MOVW 0(R0), R0 // arg 1 mib
BL libc_sysctl(SB)
MOVW R9, R13
RET
TEXT runtime·kqueue_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
BL libc_kqueue(SB)
MOVW R9, R13
RET
TEXT runtime·kevent_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
SUB $8, R13
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 keventt
MOVW 8(R0), R2 // arg 3 nch
MOVW 12(R0), R3 // arg 4 ev
MOVW 16(R0), R4 // arg 5 nev (on stack)
MOVW R4, 0(R13)
MOVW 20(R0), R5 // arg 6 ts (on stack)
MOVW R5, 4(R13)
MOVW 0(R0), R0 // arg 1 kq
BL libc_kevent(SB)
CMP $-1, R0
BNE ok
BL libc_errno(SB)
MOVW (R0), R0 // errno
RSB.CS $0, R0 // caller expects negative errno
ok:
MOVW R9, R13
RET
TEXT runtime·clock_gettime_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 tp
MOVW 0(R0), R0 // arg 1 clock_id
BL libc_clock_gettime(SB)
CMP $-1, R0
BNE 3(PC)
MOVW $0, R8 // crash on failure
MOVW R8, (R8)
MOVW R9, R13
RET
TEXT runtime·fcntl_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
SUB $8, R13
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 cmd
MOVW 8(R0), R2 // arg 3 arg (vararg, on stack)
MOVW R2, 0(R13)
MOVW 0(R0), R0 // arg 1 fd
BL libc_fcntl(SB)
MOVW R9, R13
RET
TEXT runtime·sigaction_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 new
MOVW 8(R0), R2 // arg 3 old
MOVW 0(R0), R0 // arg 1 sig
BL libc_sigaction(SB)
CMP $-1, R0
BNE 3(PC)
MOVW $0, R8 // crash on failure
MOVW R8, (R8)
MOVW R9, R13
RET
TEXT runtime·sigprocmask_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 new
MOVW 8(R0), R2 // arg 3 old
MOVW 0(R0), R0 // arg 1 how
BL libc_pthread_sigmask(SB)
CMP $-1, R0
BNE 3(PC)
MOVW $0, R8 // crash on failure
MOVW R8, (R8)
MOVW R9, R13
RET
TEXT runtime·sigaltstack_trampoline(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW 4(R0), R1 // arg 2 old
MOVW 0(R0), R0 // arg 1 new
BL libc_sigaltstack(SB)
CMP $-1, R0
BNE 3(PC)
MOVW $0, R8 // crash on failure
MOVW R8, (R8)
MOVW R9, R13
RET
// syscall calls a function in libc on behalf of the syscall package.
// syscall takes a pointer to a struct like:
// struct {
// fn uintptr
// a1 uintptr
// a2 uintptr
// a3 uintptr
// r1 uintptr
// r2 uintptr
// err uintptr
// }
// syscall must be called on the g0 stack with the
// C calling convention (use libcCall).
//
// syscall expects a 32-bit result and tests for 32-bit -1
// to decide there was an error.
TEXT runtime·syscall(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW R0, R8
MOVW (0*4)(R8), R7 // fn
MOVW (1*4)(R8), R0 // a1
MOVW (2*4)(R8), R1 // a2
MOVW (3*4)(R8), R2 // a3
BL (R7)
MOVW R0, (4*4)(R8) // r1
MOVW R1, (5*4)(R8) // r2
// Standard libc functions return -1 on error and set errno.
CMP $-1, R0
BNE ok
// Get error code from libc.
BL libc_errno(SB)
MOVW (R0), R1
MOVW R1, (6*4)(R8) // err
ok:
MOVW $0, R0 // no error (it's ignored anyway)
MOVW R9, R13
RET
// syscallX calls a function in libc on behalf of the syscall package.
// syscallX takes a pointer to a struct like:
// struct {
// fn uintptr
// a1 uintptr
// a2 uintptr
// a3 uintptr
// r1 uintptr
// r2 uintptr
// err uintptr
// }
// syscallX must be called on the g0 stack with the
// C calling convention (use libcCall).
//
// syscallX is like syscall but expects a 64-bit result
// and tests for 64-bit -1 to decide there was an error.
TEXT runtime·syscallX(SB),NOSPLIT,$0
MOVW R13, R9
BIC $0x7, R13 // align for ELF ABI
MOVW R0, R8
MOVW (0*4)(R8), R7 // fn
MOVW (1*4)(R8), R0 // a1
MOVW (2*4)(R8), R1 // a2
MOVW (3*4)(R8), R2 // a3
BL (R7)
MOVW R0, (4*4)(R8) // r1
MOVW R1, (5*4)(R8) // r2
// Standard libc functions return -1 on error and set errno.
CMP $-1, R0
BNE ok
CMP $-1, R1
BNE ok
// Get error code from libc.
BL libc_errno(SB)
MOVW (R0), R1
MOVW R1, (6*4)(R8) // err
ok:
MOVW $0, R0 // no error (it's ignored anyway)
MOVW R9, R13
RET
// syscall6 calls a function in libc on behalf of the syscall package.
// syscall6 takes a pointer to a struct like:
// struct {
// fn uintptr
// a1 uintptr
// a2 uintptr
// a3 uintptr
// a4 uintptr
// a5 uintptr
// a6 uintptr
// r1 uintptr
// r2 uintptr
// err uintptr
// }
// syscall6 must be called on the g0 stack with the
// C calling convention (use libcCall).
//
// syscall6 expects a 32-bit result and tests for 32-bit -1
// to decide there was an error.
TEXT runtime·syscall6(SB),NOSPLIT,$0
MOVW R13, R9
SUB $8, R13
BIC $0x7, R13 // align for ELF ABI
MOVW R0, R8
MOVW (0*4)(R8), R7 // fn
MOVW (1*4)(R8), R0 // a1
MOVW (2*4)(R8), R1 // a2
MOVW (3*4)(R8), R2 // a3
MOVW (4*4)(R8), R3 // a4
MOVW (5*4)(R8), R4 // a5
MOVW R4, 0(R13)
MOVW (6*4)(R8), R5 // a6
MOVW R5, 4(R13)
BL (R7)
MOVW R0, (7*4)(R8) // r1
MOVW R1, (8*4)(R8) // r2
// Standard libc functions return -1 on error and set errno.
CMP $-1, R0
BNE ok
// Get error code from libc.
BL libc_errno(SB)
MOVW (R0), R1
MOVW R1, (9*4)(R8) // err
ok:
MOVW $0, R0 // no error (it's ignored anyway)
MOVW R9, R13
RET
// syscall6X calls a function in libc on behalf of the syscall package.
// syscall6X takes a pointer to a struct like:
// struct {
// fn uintptr
// a1 uintptr
// a2 uintptr
// a3 uintptr
// a4 uintptr
// a5 uintptr
// a6 uintptr
// r1 uintptr
// r2 uintptr
// err uintptr
// }
// syscall6X must be called on the g0 stack with the
// C calling convention (use libcCall).
//
// syscall6X is like syscall6 but expects a 64-bit result
// and tests for 64-bit -1 to decide there was an error.
TEXT runtime·syscall6X(SB),NOSPLIT,$0
MOVW R13, R9
SUB $8, R13
BIC $0x7, R13 // align for ELF ABI
MOVW R0, R8
MOVW (0*4)(R8), R7 // fn
MOVW (1*4)(R8), R0 // a1
MOVW (2*4)(R8), R1 // a2
MOVW (3*4)(R8), R2 // a3
MOVW (4*4)(R8), R3 // a4
MOVW (5*4)(R8), R4 // a5
MOVW R4, 0(R13)
MOVW (6*4)(R8), R5 // a6
MOVW R5, 4(R13)
BL (R7)
MOVW R0, (7*4)(R8) // r1
MOVW R1, (8*4)(R8) // r2
// Standard libc functions return -1 on error and set errno.
CMP $-1, R0
BNE ok
CMP $-1, R1
BNE ok
// Get error code from libc.
BL libc_errno(SB)
MOVW (R0), R1
MOVW R1, (9*4)(R8) // err
ok:
MOVW $0, R0 // no error (it's ignored anyway)
MOVW R9, R13
RET
// syscall10 calls a function in libc on behalf of the syscall package.
// syscall10 takes a pointer to a struct like:
// struct {
// fn uintptr
// a1 uintptr
// a2 uintptr
// a3 uintptr
// a4 uintptr
// a5 uintptr
// a6 uintptr
// a7 uintptr
// a8 uintptr
// a9 uintptr
// a10 uintptr
// r1 uintptr
// r2 uintptr
// err uintptr
// }
// syscall10 must be called on the g0 stack with the
// C calling convention (use libcCall).
TEXT runtime·syscall10(SB),NOSPLIT,$0
MOVW R13, R9
SUB $24, R13
BIC $0x7, R13 // align for ELF ABI
MOVW R0, R8
MOVW (0*4)(R8), R7 // fn
MOVW (1*4)(R8), R0 // a1
MOVW (2*4)(R8), R1 // a2
MOVW (3*4)(R8), R2 // a3
MOVW (4*4)(R8), R3 // a4
MOVW (5*4)(R8), R4 // a5
MOVW R4, 0(R13)
MOVW (6*4)(R8), R5 // a6
MOVW R5, 4(R13)
MOVW (7*4)(R8), R6 // a7
MOVW R6, 8(R13)
MOVW (8*4)(R8), R4 // a8
MOVW R4, 12(R13)
MOVW (9*4)(R8), R5 // a9
MOVW R5, 16(R13)
MOVW (10*4)(R8), R6 // a10
MOVW R6, 20(R13)
BL (R7)
MOVW R0, (11*4)(R8) // r1
MOVW R1, (12*4)(R8) // r2
// Standard libc functions return -1 on error and set errno.
CMP $-1, R0
BNE ok
// Get error code from libc.
BL libc_errno(SB)
MOVW (R0), R1
MOVW R1, (13*4)(R8) // err
ok:
MOVW $0, R0 // no error (it's ignored anyway)
MOVW R9, R13
RET
// syscall10X calls a function in libc on behalf of the syscall package.
// syscall10X takes a pointer to a struct like:
// struct {
// fn uintptr
// a1 uintptr
// a2 uintptr
// a3 uintptr
// a4 uintptr
// a5 uintptr
// a6 uintptr
// a7 uintptr
// a8 uintptr
// a9 uintptr
// a10 uintptr
// r1 uintptr
// r2 uintptr
// err uintptr
// }
// syscall10X must be called on the g0 stack with the
// C calling convention (use libcCall).
//
// syscall10X is like syscall10 but expects a 64-bit result
// and tests for 64-bit -1 to decide there was an error.
TEXT runtime·syscall10X(SB),NOSPLIT,$0
MOVW R13, R9
SUB $24, R13
BIC $0x7, R13 // align for ELF ABI
MOVW R0, R8
MOVW (0*4)(R8), R7 // fn
MOVW (1*4)(R8), R0 // a1
MOVW (2*4)(R8), R1 // a2
MOVW (3*4)(R8), R2 // a3
MOVW (4*4)(R8), R3 // a4
MOVW (5*4)(R8), R4 // a5
MOVW R4, 0(R13)
MOVW (6*4)(R8), R5 // a6
MOVW R5, 4(R13)
MOVW (7*4)(R8), R6 // a7
MOVW R6, 8(R13)
MOVW (8*4)(R8), R4 // a8
MOVW R4, 12(R13)
MOVW (9*4)(R8), R5 // a9
MOVW R5, 16(R13)
MOVW (10*4)(R8), R6 // a10
MOVW R6, 20(R13)
BL (R7)
MOVW R0, (11*4)(R8) // r1
MOVW R1, (12*4)(R8) // r2
// Standard libc functions return -1 on error and set errno.
CMP $-1, R0
BNE ok
CMP $-1, R1
BNE ok
// Get error code from libc.
BL libc_errno(SB)
MOVW (R0), R1
MOVW R1, (13*4)(R8) // err
ok:
MOVW $0, R0 // no error (it's ignored anyway)
MOVW R9, R13
RET
|
